请大家帮我看看,电路耦合为何会改变电流的形式
本帖最后由 船行者 于 2013-1-11 10:05 编辑大家好,请大家帮我看看。
我建立了一个很简单的电路模型,其中用的独立电流源加载脉冲电流,单独电流计算结果很正确,如图,第一个是电路模型,第二个是计算结果:
这个电路模型的命令流如下:
FINISH
/CLEAR
/FILNAME,DIANLU,1
/TITLE,The DIANLU
/config,nres,2000
/PREP7
ET,1,CIRCU124,0 !定义电阻的单元类型
ET,2,CIRCU124,3,2 !定义独立电流源(施加脉冲载荷)的单元类型
ET,3,CIRCU124,5 !定义线圈(电路)的单元类型
R3=500E-3 !设置空气场区域半径
!定义实常数
R,1,0.02 !回路电阻多大
R,2,0,10,0.01,0.0001,0.0001,0.01 !定义独立电流源的电流最小值、最大值、延迟时间、上升时间、下降时间、脉冲持续时间
RMORE,0.022 !定义独立电流源的电流周期
R,3,1
N,1000000,R3,0,-0.5*R3 !设置电路单元的节点位置
N,1000001,R3,0,0.5*R3
N,1000002,1.5*R3,0,-0.5*R3
N,1000003,0,0,0
TYPE,1 !电阻
REAL,1
E,1000001,1000002
TYPE,2 !独立电流源
REAL,2
E,1000000,1000001
TYPE,3 !电路线圈
REAL,3
E,1000002,1000000,1000003
NSEL,S,NODE,,1000000
D,1000000,VOLT,0 !电路中1000000号节点接地
ALLSEL
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL
TIME,3E-2
AUTOTS
DELTIM,1E-4
SOLVE
FINISH
/POST26
NSOL,2,1000003,CURR,, !显示1000003节点的电流随时间变化图
PRVAR,2,
/AXLAB,Y,OUTPUT POTENTIAL(CURR)
PLVAR,2,
然后,我让电路与一个三维线圈进行耦合,耦合后电流就不是脉冲形式了,如图,第一个是电路-线圈耦合模型,第二个是计算结果。
有人知道这是怎么回事吗?比较急,求指点,谢谢啦!
这部分命令流如下:
FINISH
/CLEAR
/FILNAME,DIANLU,1
/TITLE,The DIANLU
/PREP7
ET,1,CIRCU124,0 !定义电阻的单元类型
ET,2,CIRCU124,3,2 !定义独立电流源(施加脉冲载荷)的单元类型
ET,3,CIRCU124,5 !定义线圈(电路)的单元类型
ET,4,SOLID97,3 !定义线圈(有限元区域)的单元类型
R3=1E-4 !设置空气场区域半径
!设置模型几何尺寸
X1=500e-3 !设置工件尺寸及位置
Y1=500e-3
t=14e-3 !设置工件厚度
X2=3e-3 !设置线圈横截面尺寸
Z2=10e-3
COIL_R_IN=0.05 !线圈内径
COIL_R_OUT=0.1 !线圈外径
g=5e-3 !线圈下表面到工件上表面距离
h=Z2/2+g !线圈中心线到工件上表面距离
X_2=250E-3 !设置线圈位置
Y_2=300E-3
Z_2=t+h
R3=500E-3 !设置空气场区域半径
rm=0.125
Z_4=t+g
Z_5=t+g+Z2
COIL_AREA=X2*Z2 !线圈横截面面积
PI=3.1415926
P=1.72E-8 !线圈的电阻率
COIL_RES=36 !线圈直流电阻
COIL_N=21 !线圈匝数
!定义实常数
R,1,0.02 !回路电阻多大
R,2,0,10,0.01,0.0001,0.0001,0.01 !定义独立电流源的电流最小值、最大值、延迟时间、上升时间、下降时间、脉冲持续时间
RMORE,0.022 !定义独立电流源的电流周期
R,3,1
R,4,COIL_AREA,COIL_N,PI*(COIL_R_OUT**2-COIL_R_IN**2)/4*Z2,0,1,0, !电路中线圈的横截面积、线圈总匝数、模型导体体积、表示电流流向的单位矢量、
RMORE,1,0.7875 !线圈对称系数、填充因子
MP,MURX,1,1 !线圈的相对磁导率
MP,RSVX,1,1.72E-8 !线圈的电阻率
LOCAL,11,1,X_2,Y_2,0 !线圈模型
CYLIND,COIL_R_IN,COIL_R_OUT,(t+g),(t+g+Z2)
VSEL,S,VOLU,,1 !设置线圈属性
VATT,1,4,4,11
ESIZE_1=0.01 !线圈网格单元尺寸
VSEL,S,VOLU,,1 !划分线圈网格
ESIZE,ESIZE_1
MSHAPE,1,3D
MSHKEY,0
VMESH,1
CSYS,0
N,1000000,R3,0,-0.5*R3 !设置电路单元的节点位置
N,1000001,R3,0,0.5*R3
N,1000002,1.5*R3,0,-0.5*R3
TYPE,1 !电阻
REAL,1
E,1000001,1000002
TYPE,2 !独立电流源
REAL,2
E,1000000,1000001
TYPE,3 !电路线圈
REAL,3
VSEL,S,VOLU,,1
NSLV,S,0 !选择绞线圈体积内部节点
*GET,NE,NODE,,NUM,MIN !选择其中节点号最大的节点
E,1000002,1000000,NE
NSEL,S,NODE,,1000000
D,1000000,VOLT,0 !电路中1000000号节点接地
ALLSEL
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL
TIME,3E-2
AUTOTS
DELTIM,1E-4
SOLVE
FINISH
/POST26
NSOL,2,NE,CURR,,
PRVAR,2,
/AXLAB,Y,OUTPUT POTENTIAL(CURR)
PLVAR,2,
求大神指点,为什么耦合会导致电流形式改变?实在不懂
仿真我不清楚,但是从实际应用来看,线圈是电感,耦合会在线圈中产生电流,电流会产生磁场,而磁场是不能突变的,所以线圈具有扼制电流突变的功能。实际是这样,仿真中出现脉冲电流变成斜坡的也就可以理解了。
大家好!引入电阻单元之后,频率不发生变化,这是为什么
我引入电阻单元之后,通过改变电阻想得到相应的谐振频率。但是结果竟然是不发生变化。请亲们给予帮助,我的命令中到底哪里出错了? wah8868 发表于 2013-1-15 10:32 static/image/common/back.gif仿真我不清楚,但是从实际应用来看,线圈是电感,耦合会在线圈中产生电流,电流会产生磁场,而磁场是不能突 ...
嗯,很有道理,谢谢啦
页:
[1]